一. 行距：
1. 每行间加一个空行
[code lang="bash"]
awk '1; { print "" }' filname.ext #输出当前行，在输出一个空行
awk '1 { print } { print "" }' filname.ext
awk '{ print } { print "" }' filname.ext
[/code]
2. 1的另外一种实现方法：
[code lang="bash"]
awk 'BEGIN { ORS="\n\n" }; 1' filname.ext #预先设置每一行的分隔符号为两个换行；你可以尝试把ORS设置为其他的看看效果如何
[/code]
3. 仅输出非空行，并每行间在加一个空行
[code lang="bash"]
awk 'NF { print $0 "\n" }' filname.ext #NF表示当前行的字段数，$0表示当前行，最后再加一个换行
[/code]
4. 双倍行距；没行间两个空行
[code lang="bash"]
awk '1; { print "\n" }' filname.ext #默认输出后会换行的，输出\n，则会输出两个空白行
[/code]
等同于：
[code lang="bash"]
awk '{ print; print "\n" }' filname.ext
[/code]
5. 显示当前行在所在文件中的行号
[code lang="bash"]
awk '{ print FNR "\t" $0 }' filname.ext #FNR，表示当前行在文件中的行号
[/code]
6. 显示当前行在本次处理过程中的行号
[code lang="bash"]
awk '{ print NR "\t" $0 }' filname.ext #NR，表示当前行在本次处理过程中的行号
[/code]
小疑问：为啥有FNR和NR的差别呢？效果不都是一样么？ 如果你给如：filname1.ext filname2.ext，你就会看到差别了。原来：FNR，是每个文件中的，换了一个文件，会归零；而NR则每个文件会累加起来的
7. 使用简单样式来输出
[code lang="bash"]
awk '{ printf("%5d : %s\n", NR, $0) }' filname.ext #行号占用5位，不足补空格
[/code]
8. 显示非空行
[code lang="bash"]
awk 'NF { $0=++a " :" $0 }; { print }' filname.ext
#NF前面说了，表示当前行的行号，此处用他作为条件，如果是空行，则NF为0，跳过；否则，用动态变量a存储非空行的数目
[/code]
9. 计算行数：效果类似wc -l
[code lang="bash"]
awk 'END { print NR }' filname.ext #END表示每行都处理完了后，在执行，此时NR就是最后一行的行号，也就是总的行数了。
[/code]
10. 计算每一行的和
[code lang="bash"]
awk '{ s = 0; for (i = 1; i <= NF; i++) s = s+$i; print s }' filname.ext
[/code]
#s用作每行和的累加，从1到NF(每行总的字段数)，依次累加
11. 计算文件中所有字段的和
[code lang="bash"]
awk '{ for (i = 1; i <= NF; i++) s = s+$i }; END { print s }' filname.ext
#s用作总和的累加，每行都处理完成了，再输出s；注意和10对比，此处没有每行清零，所以累加了。没有设置的变量，默认为空，但是会根据上下文数值计算情况自动变为0
[/code]
12. 将每个字段用其绝对值代替
[code lang="bash"]
awk '{ for (i = 1; i <= NF; i++) if ($i < 0) $i = -$i; print }' filname.ext
#$i表示当前行中的字段，$0表示当前行，可以改变$i的值
[/code]
13. 计算文件中总的字段和（例如计算单词数）
[code lang="bash"]
awk '{ total = total + NF }; END { print total }' filname.ext
[/code]
14. 计算匹配指定信息的总行数
[code lang="bash"]
awk '/Linux/ { n++ }; END { print n+0 }' filname.ext
[/code]
15. 找到文件中每行第一个字段中，最大的数，以及其所在的行
[code lang="bash"]
awk '$1 > max { max=$1; maxline=$0 }; END { print max, maxline }' filname.ext
#用max存储最大的数，maxline存储最大数所在的行，并在最后输出
[/code]
16. 显示当前行的字段数，并输出当前行
[code lang="bash"]
awk '{ print NF ":" $0 } ' filname.ext
[/code]
17. 显示每行最后一个字段的内容
[code lang="bash"]
awk '{ print $NF }' filname.ext #NF表示当前行的字段数，例如为3，则$NF，就是$3，也就是第三个字段了
[/code]
18. 显示最后一行的最后一个字段
[code lang="bash"]
awk '{ field = $NF }; END { print field }' filname.ext
#每行处理没有输出，尽在最后输出，field作为每行的最后一行的暂存变量
[/code]
19. 显示字段数小于4的行
[code lang="bash"]
awk 'NF < 4' filname.ext #{}以外的内容，作为条件，没有{}，则默认输出当前行
[/code]
20. 显示每行的最后一个字段小于4的行
[code lang="bash"]
awk '$NF < 4' filname.ext #注意和19对比
[/code]